source: hybrid/branches/releng-9.0/nanobsd/files/root/.cshrc@ 10905

# $FreeBSD: releng/9.0/etc/root/dot.cshrc 170088 2007-05-29 06:37:58Z dougb $
#
# .cshrc - csh resource script, read at beginning of execution by each shell
#
# see also csh(1), environ(7).
#

alias h         history 25
alias j         jobs -l
alias la        ls -a
alias lf        ls -FA
alias ll        ls -lA

# A righteous umask
umask 22

set path = (/sbin /bin /usr/sbin /usr/bin /usr/games /usr/local/sbin /usr/local/bin $HOME/bin /tools)

setenv  EDITOR  vim
setenv  PAGER   more
setenv  BLOCKSIZE       K

if ($?prompt) then
        # An interactive shell -- set some stuff up
        set prompt = "`/bin/hostname -s`# "
        set filec
        set histfile = /tmp/.history
        set history = 1000
        set savehist = 1000
        set mail = (/var/mail/$USER)
        if ( $?tcsh ) then
                bindkey "^W" backward-delete-word
                bindkey -k up history-search-backward
                bindkey -k down history-search-forward
        endif
endif
    
if ($?prompt) then
   # Display some tricks and pointers for management on login.
   echo ""
   echo "Statistics:"
   echo " - Build "`grep 'Revision:' /tools/wl-release.txt`
   echo " - Config "`grep Generated /usr/local/etc/wleiden.yaml | tr -d '#'`
   setenv cs_conn `arp -na | grep -v -e ' 00:15:6d' -e 'incomplete' -e 'permanent' -e ' 00:0d:b9' | wc -l`
   setenv cs_auth `pfctl -twlportal -Tshow | wc -l`
   echo " - $cs_conn clients and $cs_auth authenticated"
   echo " - "`uptime`
   echo ""
   echo "Active Bridges:"
   arp -na | grep -e ' 00:15:6d' | sed -e 's/^/ - /' | grep ' ' || echo " - none"
   echo ""
   echo "Active Neighboors:"
   arp -a | grep -v 'permanent' | grep ' 00:0d:b9' |\
     sed -e 's/^/ - /' -e 's/.wleiden.net//' -e 's/expires .*$//' |\
     grep ' ' || echo " - none"
   echo ""
endif